指南针自定义指标简介(compass网站)

指南针自定义指标简介目录

1.指南针自定义指标语法

1.1 指标文件结构

1.2 运算符

1.3 赋值语句

1.4 条件跳转语句

1.5 循环语句

1.6 指标的引用

1.7 注释

2.自定义指标语法范式

3.函数列表

3.1 引用函数

3.2 大盘函数

3.3 数学函数

3.4 统计函数

3.5 三角函数

4.指标点评

4.1 AR、BR、CR指标

4.2 SRDM(动向速比率)指标

5.指标进阶

5.1 常见错误

5.2 用指标速度测试提高指标计算速度

1. 指南针自定义指标语法

指南针自定义指标平台以高级程序语言语法为模板，定义了功能强大的自定义指标语法，支持高级语言的所有主要的程序结构——顺序、循环和条件跳转。

指南针自定义指标语法以语句为单位，每个语句都需要以“;”作结尾。在自定义指标的语法中，有三种语句：赋值语句、条件跳转语句和循环语句。

1.1. 指标文件结构

指南针指标文件（zbt或者zbu）可以直接用文本编辑器打开。但是不提倡直接在文本编辑器中改写指标文件，因为这样做容易发生语法错误，而且无法使用指标平台编辑环境的提示功能。

指标文件的结构如下（括号中是注释说明）：

__ZBT （指南针指标文件起始标志）

_NAME ……（指标文件名称，不能为空）

_COMM ……（指标文件注释，可以为空）

_PAR ……（指标的参数列表，如果有多个参数，用逗号“,”分割）

_V AR ……（指标的局部变量列表，如果有多个，用逗号“,”分割）

_ZB ……（指标的参数指标列表，即需要用到的指标列表）

_RES ……（指标文件的结果指标列表，即本文件能计算的指标列表）

_DEF ……（指标的默认值，如果在计算中发生错误，则指标值填为默认值）

_CODE （指标文件代码段起始标志）

……

……（代码段）

……

__END （指标文件结束标志）

1.2. 运算符

指南针自定义指标中支持以下运算符（按优先级从高到低排列）：

l “(”、“)”左右括号

l “*”、“/”乘、除

l “+”、“-”加、减

l “>”、“<”、“>=”、“<=”大于、小于、大于或等于、小于或等于

l “=”、“<>”等于、不等于

l “&”与，逻辑运算符，仅当两

l “|”或

l “=”赋值，注意赋值号和等于号是一样的

为了兼容中文输入的使用习惯，下列运算符“()*/+-=”支持中文全角输入。

1.3. 赋值语句

赋值语句的语法非常简单，没有关键字。赋值语句的型式有：

a =

b + c;

a = 系统函数（）;

系统函数（）;

1.4. 条件跳转语句

条件跳转语句有4个关键字：IF (表示如果)、THEN (表示则)、ELSE (表示否则)、ENDIF (表示条件语句结束)。完整的条件跳转语句的形式是：

IF 条件

THEN

语句1;

语句2;

……

ELSE

语句1;

语句2;

……

ENDIF;

“条件”的形式是型如“a > b”、“a < b”、“a = b”(注意这里的“=”是相等而不是赋值的意思)，也可以用与和或把简单条件串连起来，型如：“(a > b) & ( b > c)”、“(a = b) | (b < c)”。

“语句1”、“语句2”可以是任何语句，包括赋值、条件跳转或者循环语句。

注意条件跳转语句必须包含“THEN”分支，但是可以没有“ELSE”分支，型如：

IF 条件

THEN

语句1;

语句2;

……

ENDIF;

1.5. 循环语句

循环语句有3个关键字：LOOPBEGIN (表示开始循环)、LOOP (表示返回上一个LOOPBEGIN处继续执行)、BREAK (表示结束循环)。循环语句的一般形式是：LOOPBEGIN

语句1;

语句2;

……

LOOP;

循环语句一般是在满足一定条件时退出循环，所以循环语句一般都需要和条件语句组合使用，型如

LOOPBEGIN

IF 条件

THEN BREAK;

ENDIF;

语句1;

语句2;

……

LOOP;

1.6. 指标的引用

自定义指标中需要引用其他指标。指标的引用分为两类：引用参数指标和引用结果返回指标。

1. 参数指标的引用

引用参数指标时的一般形式是：指标名称[日期偏移](参数列表)。日期偏移是指需要引用当前天往前几天的指标数值，如果为0则表示引用当前天的指标数值，1则表示当前天往前1天的指标数值，一次类推……，注意日期偏移为0时可以不写；参数列表标示所引用的

指标的参数，如果所引用的指标没有参数则不能写该项，如果指标有多个参数，则中间用逗号（半角）分割。

例如CYF指标需要有一个参数，当引用两天前以22为参数的CYF指标应该表述为：CYF[2](22)；收盘价指标没有参数，需要引用当前天的收盘价应该表述为：CLOSE[0]或者CLOSE。

2. 结果返回指标的引用

引用结果返回指标分为两种情况，即结果返回指标出现在等号右侧和出现在等号左侧。结果返回指标出现在等号右侧时，含义是引用结果返回指标的数值，引用的一般形式是：指标名称[引用日期]注意此时不能有参数列表；结果返回指标出现在等号左侧时，含义是给结果返回指标赋值，引用的一般形式是：指标名称，注意此时不能有日期偏移和参数列表。

1.7. 注释

指南针自定义指标语法中，允许使用注释来标识语句的具体意义。注释以双斜杠“//”开始到本行的结束。在指标文本窗口中注释以绿色字体显示。

2.自定义指标语法范式

3. 函数列表

3.1. 引用函数

● BLAST( X, N )

求0～N-1周期中，最近一次条件X成立的周期到当前天的日期偏移。如果N为0，则一直搜索到第一个有效周期（上市第一天）。X是条件表达式，例如CLOSE > OPEN、CYF13 > CYF34等；N是搜索的范围。如果当前天即满足条件X，返回0，在搜索范围内条件X没有满足则返回N

举例：BLAST( CYF13 > CYF34, 10 )，表示求当前天和过去9天中最近一次CYF13 > CYF34的日期偏移。

● COST( N )

取得成本分布情况。N是一个表示百分比的表达式，如20、涨跌幅等。合法的N必须是0～100间的数，如果N小于0，则视为0，如果N大于100，则视为100。

举例：COST(20)，表示20％获利盘的价格是多少，即有20％的流通盘成本在该价格以下（获利盘），其余80％的流通盘成本在该价格以上（套牢盘）。

● COSTD( X, N )

取得价格分布情况。X是一个表示价格的表达式，如15、CLOSE、HIGH等；N是一个表示百分比的表达式，表示相对价格X的偏移。合法的N值应该是一个-100到100的数值，如果N<-100，则视为-100，N大于100，则视为100。

举例：COSTD( CLOSE, 15 )，表示求当天收盘价(1 + 15％) =115％的价格上的获利盘是多少，即有多少流通盘的成本在当天收盘价115％以下。COSTD( HIGH[1], -10 )，表示求昨天最高价(1 - 10％) =90％的价格上的获利盘是多少。

● COUNT( X, N )

求0～N-1周期中，条件X成立的周期数。如果N为0，则从第一个有效周期（上市第一天）开始搜索。X是条件表达式，例如CLOSE > OPEN、CYF13 > CYF34等；N是搜索的范围。

举例：COUNT( CLOSE > OPEN, 10 )，表示10日内K线收阳的天数。

● DMA( Z, X, A )

求X的以A为平滑因子的指数移动平均。其中Z是必须是结果返回指标，X是一个不为常数的表达式，A是平滑因子，其合理范围应该在0～1之间，如果A小于0则视为0，大于1则视为1。DMA的具体算法： Z = (1-A) × Z[1] + X × A 。 Z[1]表示前一天指标Z的数值。

举例：DMA( Z, CLOSE + OPEN, 0.2 )，表示求以0.2为平滑因子的开盘价与收盘价之和的指数移动平均值，结果存放在指标Z中。

● EMA( Z, X, N )

求X的N日指数平滑移动平均。N是一个非负整数，如果N小于0，则视为0。EMA的具体算法：Z = [(N-1)× Z[1]+ 2×X]/(N+2)

举例：EMA( Z, CYF13[1], 10 )，表示对当前天的前一天的CYF13指标作10日指数平滑移动平均，结果存放在指标Z中。

● HHV( X, N )

求N周期内X的最大值。X应该是一个不为常数的表达式，N是一个非负表达式，表示周期范围，如果N为0表示从第一个有效周期（上市第一天）开始计算。

举例：HHV( (OPEN + HIGHT + LOW + CLOSE) / 4, 10 )，表示求10天内的最高均价。

● HHVB( X, N )

求N周期内X值最大的周期到当前周期的日期偏移。X和N的含义同HHV(X,N)。如果X的最大值出现在当前周期，函数返回0。

举例：HHVB( (OPEN + HIGHT + LOW + CLOSE) / 4, 10 )，表示求10天内的最高均价出现日期到当前天的偏移值。

● KLINEINDEX

求当前周期是K线链上的第一个节点。如果当前是上市第一个周期，函数返回0；第二个周期，函数返回1；……

● LFCAST( X, N )

求X的N周期线形回归值。X应该是一个不为常数的表达式，N是一个非负表达式，表示在多少周期内作线性拟合，如果N为0表示从第一个有效周期（上市第一天）开始拟合。

举例：LFCAST( CYF34, 0 )，表示对股票上市以来指标CYF34的线性拟合值。

● LLV( X, N )

求N周期内X的最小值。X应该是一个不为常数的表达式，N是一个非负表达式，表示周期范围，如果N为0表示从第一个有效周期（上市第一天）开始计算。

举例：LLV( (OPEN + HIGHT + LOW + CLOSE) / 4, 20 )，表示求20天内的最低均价。

● LLVB( X, N )

求N周期内X值最小的周期到当前周期的日期偏移。X和N的含义同LLV(X,N)。如果X的最小值出现在当前周期，函数返回0。

举例：LLVB( (OPEN + HIGHT + LOW + CLOSE) / 4, 20 )，表示求20天内的最低均价出现日期到当前天的偏移值

● LSLOPE( X, N )

求X的N周期线形回归线的斜率。X应该是一个不为常数的表达式，N是一个非负表达式，表示在多少周期内作线性拟合，如果N为0表示从第一个有效周期（上市第一天）开始拟合。

举例：LSLOPE( CYF13, 0 )，表示对股票上市以来指标CYF13的数值作线性拟合后的直线斜率。

● MA( X, N )

求X的N周期简单平均值。X应该是一个不为常数的表达式，N是一个非负表达式，表示在多少周期内作平均，如果N为0表示从第一个有效周期（上市第一天）开始计算。MA的具体算法是：

举例：MA( CLOSE[1] + OPEN, 20 )，表示20个周期内，每日的前收加上今开的平均值。

● SMA( Z, X, N, M )

求X的N日指数移动平均，平滑因子a = M / N。其中Z是必须是结果返回指标，X是一个不为常数的表达

式，M的数值应该小于N的数值。SMA的具体算法是：

举例：SMA( Z, CYF13, 10, 5 )，表示对CYF13作平滑因子为5/10=0.5的指数移动平均。

● SUM( X, N )

求X的N周期简单累加值。X应该是一个不为常数的表达式，N是一个非负表达式，表示在多少周期内作简

单累加，如果N为0表示从第一个有效周期（上市第一天）开始计算。

举例：SUM( CLOSE[1] + OPEN, 20 )，表示20个周期内，每日的前收加上今开的简单累加值。

● SUMD( X, N, D )

求X的N周期衰减累加值。X应该是一个不为常数的表达式；N是一个非负表达式，表示在多少周期内作简单累加，如果N为0表示从第一个有效周期（上市第一天）开始计算；D是相对日期偏移的衰减系数，D应该小

于N。

举例：SUMD( CLOSE - OPEN, 5, 1 )，表示5个周期内的当日涨的衰减累加，即 (CLOSE - OPEN) + (CLOSE[1] - OPEN[1]) * 4 / 5 + (CLOSE[2] - OPEN[2]) * 3 / 5 + (CLOSE[3] - OPEN[3]) * 2 / 5 + (CLOSE[4] - OPEN[4]) / 5

3.2. 大盘函数

● S0( X )

引用指南针0号指数的数值，X是一个不为常数的表达式。

举例：S0( CLOSE[1] + OPEN )，表示求0号指数当前周期的前收加今开的数值。

● S0A01( X )

引用指南针0A01指数的数值，X是一个不为常数的表达式。

举例：S0A01( 成交量 )，表示求0A01指数当前周期的成交量的数值。

● S0AMV( X )

引用指南针0AMV指数的数值，X是一个不为常数的表达式。

● S0DMV( X )

引用指南针0DMV指数的数值，X是一个不为常数的表达式。

3.3. 数学函数

● ABS( X )

取绝对值，ABS(X) = |X|。

● DERIV( Z, X )

求X的导数，结果存放在Z中。Z应该是结果返回指标，X是一个不为常数的表达式。举例：DERIV( Z, CLOSE[1] )，表示求前收的导数。

● EXP( X )

求e的X次方，EXP(X)=e x。

● INTEGER( X )

X向下取整，。

● LN( X )

求X的自然对数。

● LOG( X )

求X的以10为底的对数。

● MAX( A, B )

求A、B中的较大值。

● MIN( A, B )

求A、B中的较小值。

● MOD( X, N )

求X模N的值，

● POW( X, N )

求X的N次方，

● SGN( X )

取X的符号，如果X是正数，返回1；如果X是负数返回-1；如果X是0，返回0。

● SQRT( X )

取X的平方根，

3.4. 统计函数

● AVEDEV( X, N )

求X的N日平均绝对差。X应该是一个不为常数的表达式，N是一个非负表达式，表示在多少周期内作统计。

举例AVEDEV( CLOSE – OPEN, 10 )，表示统计10日内的当日涨跌的平均绝对差。

● DEVSQ( X, N )

求X的N日偏差均方和。X应该是一个不为常数的表达式，N是一个非负表达式，表示在多少周期内作统计。

举例DEVSQ( CLOSE – OPEN, 10 )，表示统计10日内的当日涨跌的偏差均方和。

● STD( X, N )

求X的N日估算标准差。X应该是一个不为常数的表达式，N是一个非负表达式，表示在多少周期内作统计。

举例STD( CLOSE – OPEN, 10 )，表示统计10日内的当日涨跌的估算标准差。

● STDP( X, N )

求X的N日总体标准差。X应该是一个不为常数的表达式，N是一个非负表达式，表示在多少周期内作统计。

举例STDP( CLOSE – OPEN, 10 )，表示统计10日内的当日涨跌的估算标准差。

● VAR( X, N )

求X的N日估算样本方差。X应该是一个不为常数的表达式，N是一个非负表达式，表示在多少周期内作统计。

举例VAR( CLOSE – OPEN, 10 )，表示统计10日内的当日涨跌的估算样本方差。

● VARP( X, N )

求X的N日总体样本方差。X应该是一个不为常数的表达式，N是一个非负表达式，表示在多少周期内作统计。

举例VARP( CLOSE – OPEN, 10 )，表示统计10日内的当日涨跌的总体样本方差。

3.5. 三角函数

● ACOS( X )

求X的反余弦值。X取值应该在0～1范围内，如果X小于0，则视为0；如果X大于1，则视为1。返回值在0～之间。

● ASIN( X )

求X的反正弦值。X取值应该在0～1范围内，如果X小于0，则视为0；如果X大于1，则视为1。返回值在～之间。

● ATAN( X )

求X的反正切值。返回值在0～之间。

● COS( X )

求X的余弦值，X的单位是弧度，返回值在-1～1之间。

● SIN( X )

求X的正弦值，X的单位是弧度，返回值在-1～1之间。

● TAN( X )

求X的正切值，X的单位是弧度。

4. 指标点评

4.1. AR、BR、CR指标

我们通过介绍AR、BR、CR指标的实现代码，进一步说明赋值、条件跳转和循环三种基本语句的应用。指标的代码如下：

—————————————————————————————————

指标名称：ABCR 指标注释：（空）默认值：0

输入参数：M 局部变量：V1, V2, V3, V4, V5, V6, AV, I

参数指标：开盘价, 最高价, 最低价, 收盘价结果指标：AR, BR, CR

指标文本：

—————————————————————————————————

T1 = 0;

T2 = 0;

T3 = 0;

T4 = 0;

T5 = 0;

T6 = 0;

I = 0;

LOOPBEGIN

IF( I = M )

THEN BREAK;

ENDIF;

T1 = T1 + HIGH[I] - OPEN[I];

T2 = T2 + OPEN[I] - LOW[I];

IF( HIGH[I] > CLOSE[I+1] )

THEN T3 = T3 + HIGH[I] - CLOSE[I+1];

ENDIF;

IF( OPEN[I] > CLOSE[I+1] )

THEN T4 = T4 + OPEN[I] - CLOSE[I+1];

ENDIF;

AV = (HIGH[I+1] + LOW[I+1]) / 2;

IF( HIGH[I] > AV )

THEN T5 = T5 + HIGH[I] - AV;

ENDIF;

IF( AV > LOW[I] )

THEN T6 = T6 + AV - LOW[I];

ENDIF;

I = I + 1;

LOOP;

AR = T1 / T2;

BR = T3 / T4;

CR = T5 / T6;

—————————————————————————————————

下面详细分析指标的代码段，文本的一开始是7条赋值语句，分别把7个局部初始化为0；

T1 = 0; //赋值语句

T2 = 0;

T3 = 0;

T4 = 0;

T5 = 0;

T6 = 0;

I = 0;

接下来是一个循环体：

LOOPBEGIN //循环开始，I是循环控制变量

IF( I = M ) //条件跳转语句，控制循环结束

THEN BREAK; //结束循环的分支

ENDIF;

……

I = I + 1; //赋值语句，循环控制变量赋值

LOOP; //循环结束

联系前面的赋值语句I=0 、循环中的赋值语句I=I+1以及控制循环的条件跳转语句可以发现，这是一个参数M次的循环，例如如果参数M为10时，这个循环需要执行10次。

在循环体中有4条赋值语句和5条条件判断语句我们举例说明，

T1 = T1 + HIGH[I] - OPEN[I];

意思是把当前天的前面第I天的最高价和开盘价的差值加到局部变量T1中；

T2 = T2 + OPEN[I] - LOW[I];

是说把当前天往前第I天的开盘价和最低价的差值加到局部变量T2中；

IF( HIGH[I] > CLOSE[I+1] )

THEN T3 = T3 + HIGH[I] - CLOSE[I+1];

ENDIF;

如果当前天前面第I天的最高价大于第I+1天的收盘价，则把当前天往前第I天的最高价和第I+1天的收盘价的差值加到局部变量T3中；

AV = (HIGH[I+1] + LOW[I+1]) / 2;

是说把前天往前第I+1天的最高价和最低价的平均值赋给局部变量AV；

最后是三句赋值语句，分别给三个结果返回指标赋值。

AR = T1 / T2;

BR = T3 / T4;

CR = T5 / T6;

4.2. SRDM（动向速比率）指标

SRDM（动向速比率）指标是一个经典指标，我们通过这个指标的实现代码，进一步说明指南针指标平台中函数的应用。

—————————————————————————————————

指标名称：SRDM 指标注释：动向速比率默认值：1.000

输入参数：N 局部变量：

参数指标：最高价, 最低价结果指标：SRDM_DMZ, SRDM_DMF, SRDM_SRDM, SRDM_ASRDM, SRDM_ADMZ, SRDM_ADMF 指标文本：

—————————————————————————————————

IF( (最高价 + 最低价) <= (最高价[1] + 最低价[1]) )

THEN SRDM_DMZ = 0;

ELSE SRDM_DMZ = MAX( ABS(最高价 - 最高价[1]), ABS(最低价 - 最低价[1]) );

ENDIF;

IF( (最高价+最低价) >= (最高价[1]+最低价[1]) )

THEN SRDM_DMF = 0;

ELSE SRDM_DMF = MAX( ABS(最高价 - 最高价[1]), ABS(最低价 - 最低价[1]) );

ENDIF;

SRDM_ADMZ = MA( SRDM_DMZ, 10 );

SRDM_ADMF = MA( SRDM_DMF, 10 );

IF( SRDM_ADMZ > SRDM_ADMF )

THEN SRDM_SRDM = (SRDM_ADMZ - SRDM_ADMF) / SRDM_ADMZ;

ELSE

IF( SRDM_ADMZ = SRDM_ADMF )

THEN SRDM_SRDM = 0;

ELSE SRDM_SRDM = (SRDM_ADMZ - SRDM_ADMF) / SRDM_ADMF;

ENDIF;

ENDIF;

SMA( SRDM_ASRDM, SRDM_SRDM, N, 1 );

—————————————————————————————————

这里着重分析指标代码中的函数调用。在第一个条件跳转语句IF……ENDIF的ELSE分支是一个赋值语句：

SRDM_DMZ = MAX( ABS(最高价 - 最高价[1]), ABS(最低价 - 最低价[1]) );

语句的含义是取相邻两天最高价差值的绝对值与最低价差值绝对值中较大的数值，赋给指标SRDM_DMZ。从这里可以发现，指标平台支持多重函数调用，即函数中再套函数，这种调用的套用次数没有限制。

代码的的最后是一个调用SMA函数的赋值语句：

SMA( SRDM_ASRDM, SRDM_SRDM, N, 1 );

这个语句的含义是对指标SRDM_SRDM作N日指数移动平均，平滑系数是1/N。注意，DMA、EMA、SMA这一类函数的第一个参数必须是结果返回指标，函数计算是会把结果直接赋给第一个参数，所以可以不写赋值部分，这条语句也可以这样写：

SRDM_ASRDM = SMA( SRDM_ASRDM, SRDM_SRDM, N, 1 );

实际上这两种写法是完全等价的。

5. 指标进阶

5.1. 常见错误

技术指标是量化分析和设计操作方法的基础，每个自定义指标都可以反映作者对股市的独特简介。指南针自定义指标平台推出以来，广大网员编写了许多指标，其中有许多精品，但是也有一些普遍性的错误，在本章中列举一些常见的错误类型，供广大网员参考。

5.1.1. 条件语句没有考虑所有情况

条件跳转语句属于分支结构，每个条件跳转语句都应该有两个分支——条件满足和条件不满足，原则上两个分支都需要考虑。请看下面指标TEST的实现代码（结果指标是TEST和AA）：

IF( CLOSE > OPEN )

THEN AA = CLOSE;

ENDIF;

TEST = MA( AA, 10 );

这种类型的代码在指标平台的实际使用中很常见。我们先看条件跳转语句，如果今天K线收阳（CLOSE > OPEN），则结果指标AA赋值为CLOSE，下面直接把AA作简单移动平均赋值给结果指标TEST。但是如果今天K线不收阳（CLOSE<=OPEN）那？此时结果指标AA没有被赋值，接下来对AA作MA运算是没有意义的，此时指标TEST的数值可能会和用户原来的设想大相径庭。

依据实际情况，这段代码有多种修改方法，例如：

IF( CLOSE > OPEN )

THEN AA = CLOSE;

ELSE AA = OPEN;

ENDIF;

TEST = MA( AA, 10 );

或者

AA = 0;

IF( CLOSE > OPEN )

THEN AA = CLOSE;

ENDIF;

TEST = MA( AA, 10 );

可以看出，第一种修改方法把条件跳转的两个分支都考虑进去了，而第二种方法则是先对指标AA赋初始值，然后无论接下来的条件跳转语句是否会对AA赋值，AA的数值都是有意义的。

5.1.2. 循环语句不能正常退出

技术指标是量化分析和设计操作方法的基础，每个自定义指标都可以反映作者对股市的独特简介。指南针自定义指标平台推出以来，广大网员编写了许多指标，其中有许多精品，但是也有一些普遍性的错误，在本章中列举一些常见的错误类型，供广大网员参考。

有两种循环语句：一种明确知道循环次数，另一种则不明确知道循环次数。无论哪种循环语句，在实际使用中都经常出现循环不能正常退出的错误。

1）明确知道循环次数的循环语句

明确知道循环次数的循环语句的一般形式如下（I是局部变量，用来控制循环次数，称为循环控制变量）：

I = 0;

LOOPBEGIN

IF( I >= 10 )

THEN BREAK;

ENDIF;

…… //

I = I + 1;

LOOP;

具体来说，这种循环语句由三部分构成：循环控制变量（I）赋初值；通过I值判断是否需要退出循环；累加I。这三个部分是缺一不可的。但是，实际使用中缺经常出现类似下面的代码：

LOOPBEGIN

IF( I >= 10 )

THEN BREAK;

ENDIF;

……

I = I + 1;

LOOP;

或者

I = 0;

LOOPBEGIN

IF( I >= 10 )

THEN BREAK;

ENDIF;

……

LOOP;

第一中情况中，循环控制变量I没有赋初值就直接进入循环，此时I值没有意义，所以无论是接下来的条件判断语句或者累加I的操作都变成没有意义了。第二种情况则是忘了写累加I的语句，此时I一直是0，条件语句恒不满足，是个不能退出的死循环。

2）不明确知道循环次数的循环语句

先观察一个实际指标的实现代码（F、N是局部变量，）：

F = 0; //用来累加“换手率”

N = 0;

LOOPBEGIN

IF( F > 100 )

THEN BREAK;

ENDIF;

……

F = F + 换手率[N];

N = N + 1;

LOOP;

这个循环语句的结束条件是累加换手率超过100。从设计思想上来说没有错，但是，如果新股刚上市，所有交易日的换手率加起来也不到100，则这个指标就出现问题了，此时循环可能无法退出。应该改为下面的写法：

F = 0; //用来累加“换手率”

N = 0;

LOOPBEGIN

IF( (F > 100) & (KLINEINDEX <= 0) )

THEN BREAK;

ENDIF;

……

F = F + 换手率[N];

N = N + 1;

LOOP;

比较两段代码，可以发现第二段代码中增加了一个退出循环的条件：如果到了上市第一天，也退出循环。通过增加这个条件，避免了新股刚上市的问题。