使用VBA编写自定义函数(修改版)

使用VBA编写自定义函数

前言

本教程仅适用于不懂或初学VBA的朋友。

万事开头难，VB的内容繁多庞杂，没接触过VB但想学习编程的朋友可能无所适从，然而，这也远不是一个小教程能说得明白的，所以，本教程没有讲过多的语法、函数，也没有摘录VBA帮助（可以算是主要的参考教程）里的内容，而是以口语的方式讲解编程的一个基本思路，再辅以讲解平常可能遇到情况，让学习者能基本上手编写一段简单的代码，我的目的就达到了，接下去，就是学习者自己去论坛找资料学习了。

一、VBA简介

Visual Basic for Applications（VBA）基于Visual Basic的一种宏语言，是微软用来扩展Windows的应用程序，特别是在Microsoft Office软件中执行通用的自动化(OLE)任务的编程语言。它与VB不同的是，VB的对象主要是可视化窗口，VBA的对象则主要是Microsoft Office应用程序，如EXCEL的单元格、工作表、工作薄等。由于对象不同，那么，对象的属性、方法、事件就会发生相应的变化，所以，学习VBA，或从VB转到VBA，就是要根据具体对象特性而进行不同的处理。

我们在使用EXCEL时，如果仅仅只限于简单的数据处理，那就完全没有发挥出EXCEL强大的功能，我们完全可以使用VBA让我们的工作效率大大提高。

一般情况下，我们通常编写三类程序：

1、自定义函数：它与工作表内置函数使用方法一样，使用简单，适用于固定几个参数得出结果这种类型；

2、表格处理，这种编程较为复杂，适用于对整表进行大批量量数据的处理，对表格进行美化处理等。

3、可视化窗口，可以通过窗口设置对表格数据进行处理。

以上三种并不是独立存在的，可以相互结合使用，更能发挥更大的效率。

本次讲解的主要自定义函数，从较为简单的独立的自定义函数开始，逐渐学习进行大数据处理的能力。

二、几个必须知道的基础知识

1、VBA编辑、使用的相关说明

打开VBE编辑器

EXCEL2003版

EXCEL2007及其以上版本

创建模块，并在模块中编写代码

如果代码（宏）保存在某一个工作薄内（比如A.xls），无论这个A.xls拷贝到任何电脑上，都可以使用这个宏，而其他工作薄要使用这个宏，就必须同时也打这个A.xls；

如果我们把包含程序（宏）的工作薄另存为加载宏文件（xla），并让EXCEL加载它，那么每次EXCEL打开时，都会自动加载这个xla文件，那么当前电脑上所有的工作薄都可以使用这个宏。

宏安全（EXCEL2007及其以上版本在信任中心中设置）

2、对象三要素：属性、事件、方法

对象代表应用程序中的元素（一个实体），比如，工作表、单元格、图表、窗体，或是一份报告、一个人物等。

属性：是指对象的特征，诸如大小、颜色或屏幕位置等；比如单元格的内容，填充颜色、字体颜色、单元格行高及列宽等等，又比如，一个人的年龄、姓名、性别、体重、血型等等。可以通过修改对象的属性值来改变对象的特性。

代码通常写为：对象.属性；好比是张三(.的)年龄

方法指的是对象能执行的动作；比如在单元格添加一个有效性序列（下拉菜单）。

代码通常写为：对象.方法；好比是领导（.下达）政令。

事件是一个对象可以辨认的动作，像单击鼠标或按下某键等，并且可以写某些代码针对此述动作来做响应；比如领导写字。

提示：不同的对象有不同的属性和方法。在VBA模块窗口里，写下一个对象的名称，再写一个.就会出现一个下拉列表，列表里就是该对象的属性和方法集合。

方法与事件的区别，方法好比是一个对象的能力，事件好比是一个对象的动作，不同的人有不同的能力，好比大多数人都能写字，但只有领导才有能力下达政令。对象及其三要素是编程的最基本知识，任何程序语言都如此。

3、数据类型

数据类型，简单来说，就是一个数据它是什么类型的内容，是数字还是文本，或是日期等等，不同的数据类型，程序处理的方法是不同的，处理时数据时所消耗的系统内存也是不一样的。

我们一般常用的几个数据类型有：Byte、Boolean（真假）、Integer 和 Long（长整数）、Single 和 Double（小数）、String（文本字符串）、Date（日期）等。

4、变量

变量好比就是方程式中的未知数Ｘ。首先，它只是一个代号（先命名），其次，我们可以给这个代号设置不同的内容（附值）。所以，这个代号的值是不固定的，是会变化的，我们可以用这个代号来任意处理需要计算的内容。于是我们把这个代号称为变量。

变量是相对于常量而言的，常量是固定的内容，比如：π、密度、65，8，-2.3等具体的数值、指定的内容或名称，变量则是相对于不同的情况来设置一个代号。

比如我们要计算一个圆的面积，常量则是π，变量则是半径或直径，当设置给圆不同的半径或直径时，圆的面积就会相应的改变。相对于整个计算而言，我们也可以说，变量就是其中需要处理的数据，而常量则是不变的计算步骤；相对于目标而言，变量就是不同的方法，而常量就是意志和决心。

变量名称：当在 Visual Basic 的模块中为过程、变量命名时，应符合下列命名规则：

①一个字符必须使用英文字母，例如，象1xb、_w这种名称都是错误的，而xb1、w_这

样的名称才是正确的。

②不能在名称中使用空格、` 、~、!、@、、#、$、%、^、&、*、(、)、-、+、=、{、}、

[、]、|、\、;、:、'、"、<、>、,、.、?、/等字符，也就是说，除了字母、数字、下划线_ 可以使用外，其他键盘上的符号都不能使用，而且，一般情况下，名称最好

不要使用全角字符或汉字。

③称的长度不得超过 255 个字符。

④称不能与 Visual Basic 本身的函数、属性、方法的名称相同。例如，命名为 Left 的

变量与函数 Left() 的名称相同，这是不允许的。在VBA中也不要使用如A1、B2等

与单元格相同的命名。

⑤能在范围的相同层次中使用重复的名称。例如，不能在同一过程中声明两个命名为

age 的变量。

注意 ：Visual Basic 不区分大小写，但它会在名称被声明的语句处保留大写，例如：Ax4d 与 ax4D 是相同的名称。

参考：可以使用单词、拼音或词组的简拼加前后缀的方式，以帮助记忆和理解，比如，我编写的YCH()自定义函数就是以我自己的名字命名的。

变量的附值，书写格式为：变量 = 值 或 表达式，比如：

A = 0.5

A = A + 1

A = A & “VBA“

为什么A可以等于A+1，因为它不是我们普通数学表达式，而是代码表达式，程序是按顺序逐行处理的，前面附了值以后，下面就会自动代入先前的值，如果前面没有附过值，这时，变量A会自动是0 或 ““（空）。所以，第1行A的值为0.5，第2行A的值为0.5+1=1.5，第3行A的值为1.5VBA。

5、单元格的表示方法

在EXCEL VBA里，最基本的元素就是单元格，通常单元格有以下几种表示方法：

单独的单元格：

①Range(“A1“)

②[A1]

③Cells(1,1)————前1表示行，后1表列

④Y.Offset(1, 2)——此为相对引用，表示Y（某个单元格）向下一行，向右2列的那

个单元格，比如，Y为A1单元格，则本代码表示的单元格是C2

单元格区域：

⑤Range(“A1:B5“)

⑥[A1:B5]

⑦Range(Cells(1,1),Cells(5,2))

⑧Range(“MyRange“)——引用命名区域，比如本工作表上有一个区域命名为MyRange

⑨Range(“A1:B5,C2:E4,G1:I10“) 引用多个区域

本工作表上所有单元格（相当于选中行标和列标在左上角交汇的那个空白处）

Cells.ClearContents

整行表示：

Rows(1) ————第一行

Rows(“1:1“) ———第一行

Rows(“1:5“) ———第一行至第五行

Rows ——————工作表上所有的行

整列表示：

Columns(1) ———第一列

Columns("A") ——第一列

Columns("A:B") —第一列至第二列

Columns ————工作表上所有的列

6、过程

代码并不是零星散乱的随便写在模块里就可以的，它是以一段段以Sub 宏名称() 语句开始，End Sub 语句结束组成的过程，其语句结构如下：

Sub 宏名称()

过程代码

End Sub

但一个过程不可能无限长，即过程代码不能无限多，在VB或VBA中，过程代码大概只能写300多行，超过了程序可能就不执行了。

如果代码过多，那么，我们可以分段写，然后，其他过程再引用执行这段代码就可以了。

Sub 过程1()

过程2

过程3

End Sub

Sub 过程2()

过程2代码

End Sub

Sub 过程3()

过程4

过程3代码

End Sub

Sub 过程4()

过程4代码

过程5

End Sub

Sub 过程5()

过程5代码

End Sub

当然，过程不是直接把代码分几段来连接，而是针对不同的情况，每个小过程单独处理一种数据，或一种处理方式，然后把这些小过程集合起来，就形成了一个大的程序，来处理全部的数据。

我们平常在编写过程中，要注意哪些数据的处理是我们经常会遇到的，那么，对这种数据的处理，可以对应编写一个独立的处理过程，今后在处理大数据时，如果其中用得着这些独立过程，就可以直接引用这个了，而不必重新编写。高塔是一砖一木搭建起来的，而每一砖一木都是独立的，我们编写程序代码也一样，只要注意经常积累这些完善而独立的小过程，将来编写大程序时，直接拿来引用即可，这样就能省去很多功夫，也能构建我们自己的程序高塔。

另外要注意，过程要按照顺序和需要递渐引用，不要形成循环引用，比如 Sub 过程1()

过程2

End Sub

Sub 过程2()

过程1

End Sub

象这样的话，那程序就会无限循环执行下去了，当然，不只是过程，在过程代码的某些循环语句中，如果设计考虑得不周，也可能会形成无限循环，如果发生这种状况，按ESC键可让程序中止。

7、学习VBA的方法和途径

最好找一个懂VB的师父带，因为任何书本、资料、教学录像都是死的，它不能回答你具体遇到的问题，只有人才是活的教学。

在网上寻找相应的OFFICE论坛学习，如：EXCELHOME

VBA帮助：在VBE窗口可以按F1调出帮助，也可以在把光标点在需要学习的代码名称上，再按F1调出这个代码的相应帮助内容。

使用录制宏功能，参考EXCEL本身是编写的代码。

注意收集好的代码。

8、如何让代码更高效，运行得更快

我在这方面水平不够，只能大概说说：

首先，必须要学会更高级的编程知识和编写技巧，这样才能编写出高效的代码；

其次，要有严密而有效的逻辑思维能力；

关闭屏幕更新，代码为：Application.ScreenUpdating = False，为True时打开屏幕更新；运行宏时如果不关闭，会发现表格随着数据的输出在自动移动，关闭后就不会移动了。

处理工作表和单元格时，除非需要，不要去选择单元格（相当于用鼠标点先单元格），比如我们要在A1单元格写入123，录制宏的代码如下：

Range("A1").Select

ActiveCell.FormulaR1C1 = "123"

其中，.Select就是单元格对象被选择到，其实这个代码可以改写为： Range("A1").FormulaR1C1 = "123" 或Range("A1") = "123"

使用数组来处理数据组；

尽可能少的使用循环语句

其他，等等。

三、实例设计讲解

1、编写目标

我们现在需要编写一个计算矩形面积（或长方形体积）的自定义函数。

2、查找相关资料

查找到矩形面积的计算公式为：长×宽

长方体的体积公式为：长×宽×高

3、分析

计算公式中，长、宽、高都是变量，可以分别设为变量1、变量2、变量3

其中：参数高可以有，也可以没有

计算结果根据需要可以是公式的结果（数值）也可以是公式本身（文本），可设为变量4

4、过程结构设计

可以制作一个步骤流程图，让代码编写的思路更加清晰。

5、编写代码

①声明自定义函数名称

声明：就是告诉程序，这个XX是专属名称，在本程序中只能用来表示XXXXX。

语法为：

Function 函数名称（必要参数, Optional 可选参数）定义函数的数据类型 过程代码

[Exit Function]

过程代码

End Function

说明：

Function：起始句，使用Function声明以下过程为自定义函数。

函数和参数其实都是变量，所以，它们名称的命名规则都与变量名称的命名规则相同。

同变量一样，如果需要的话也可以对函数定义数据类型，也可以不用定义，那么，函数的数据类型就是“用户自定义”类型。

可以没有参数，那就如同工作表函数PI()一样，它输出的结果就始终只有一个，即它就是一个常量。

可以只有必要参数，也可以只有可选参数。

如果必要参数和可选参数都有，那么，可选参数必须放在必要参数后面，可选参数必须使用Optional声明。

可选参数可以指定一个常量，表示在没有写入该可选参数时，默认它为这个常量，比如Optional可选参数 = 3.5；必要参数不能指定常量。

参数都可以声明数据类型，也可以不用声明，那么，未声明数据类型的参数就是“用户自定义”类型。

[]是常规的表示方法，表示其中的内容可以有，也可以没有。

Exit Function：在过程中任意位置，都可以使用该语句结束该函数的计算过程。

End Function：函数过程的最终结束处。

过程：从Function起始 到 End Function结束，其中所有的内容称之为过程。

②设置参数

Function YJX（C As Single, K As Single, Optional G As Single, Optional JG As Integer = 0）

…

End Function

说明：

本次用YJX表示函数名称，C表示长，K表示宽，G表示高，JG表示结果样式 其中，G(高) 和JG（结果样式）参数不一定存在，所以声明为可选参数。

参数在声明数据类型时，语句必须是：变量名 As 类型名称

很显然，C(长)、K(宽)、G(高)都必须是数值，所以定义为Single（小数）

JG（结果样式）用整数来表示就足够了，我们可以设置为：

当JG=0时，输出公式的计算结果，当JG=1时，输出公式本身。

因为我们设置了Optional JG As Integer = 0，即没有这个参数时，就默认为输出计算结果。

因为该函数的输出结果可能是一个数值，也可以是一个文本，所以，不对该函数进行数据类型的声明。

我们在工作表中实际使用这个函数时，公式写法就是：

=YJX(长,宽[,高][,结果样式])

注意：当你计算的是矩形面积时，而且需要输出计算公式时，是没有高这个参数的，那就应该这样写：

=YJX(3,4,,1)——表示输出长=3宽=4的矩形面积公式

即，后面的可选参数没有时可以不管，但前面的可选参数没有时，必须加个逗号表示。

③定义变量

起始行以下，紧接着就是设置本过程的变量，当然，如果计算过程中不需要其他的变量，也可以不设置，本次设置一个变量 GS,该变量是程序在内存处理数据中使用，使用者在工作表使用函数时，不会涉及到。

Function YJX（C As Single, K As Single, Optional G As Single, Optional JG As Integer = 0）

Dim GS

…

End Function

说明：

定义变量的语句为：Dim 变量名称 As 数据类型名称

也可以使用类型通配符来表示，比如，Dim GS%，表示GS是一个整型变量。当不确定GS 只附值整数时，可以不用指定，让它成为一个用户自定义类型。

④检查错误

检查输入的参数是否正确，以及数据关系是否正常，是保证程序在处理数据时，不会因为数据错误而导致程序中断的必要保障，是任何一个程序员编程时必需要做的功课。假如我们的函数是这样的一个写法：= YJX(3,将军)，即实际的计算公式为：3*将军，你认为它能计算出结果么？

所以，要养成在计算之前先检查变量错误的良好习惯，这样编写出来的代码才不会有BUG。

实际上，在自定义函数中，已定义了数据类型的变量是可以不用检查的，如果你已经定义了参数是Single（小数），而你输入的是String（文本）时，那程序会马上中断进程，工作表中会显示#VALUE!；如果你没有定义参数类型，即参数为用户自定义类型时，程序会使用该变量继续计算，直到发生错误后中断进程，但这样一来加重了系统的负担，让它多运算了一些内容，虽然表面上看起来，似乎也没有什么差别，但如果一个计算表中，有一万个函数在同时运算时，这种差别（计算延时）就很明显了。

本函数中，矩形或长方体的长宽高参数都应该是＞0的，但如果参数的是负值，我们则认为是错的，但负值也是数值，程序可不知道你是怎么想的，如果你不要求程序检查这个错误，程序就认为参数是正确的，依旧会计算出结果来。所以必须添加对参数是否为负值的检查代码：If IsMissing(C) = False And C < 0 Then '如果 条件符合 那么 YJX = 1 / 0 ' 结果1

Exit Function

Else '否则

YJX = "正确" ' 结果2

End If '结束

说明：

对代码进行注释时，前面加’；注释可以单独写一行，也可以放在代码语句的后面。

IsMissing()为VB函数，作用是判断一个过程的参数是否存在，不存在时为True(真),存在时为False(假)；VB中所有这种判断真假的函数，当判断条件为真时，可以省略 “= True”，比如：

If IsNumeric(C) Then '表示：如果JC是数值

If IsNumeric(C) = False Then '表示：如果JC不是数值

And和Or是逻辑运算符，And表示前后条件需要同时成立或同时不成立，Or表示前后条件只需要其中一个成立或不成立即可。

上面代码表示的意思是：如果参数C存在（IsMissing(C) = False）而且C < 0，则函数结果显示为“长小于0！”（结果1），并且退出进程，否则，函数显示“正确”（结果2）。

我们看到结果1有两个语句：

YJX = 1 / 0 '表示参数错误时，我们让函数结果为1/0，即它是个错误值

Exit Function '然后接着退出过程，即中断处理。

为什么要让YJX = 1 / 0呢？直接中断不就可以了么。如果是这样，那么错误参数的计算结果为0，0也是数值，你在数据表最后SUM汇总的结果也仍然是数值，如果数据表有成千上万行，那你根本就发现不了哪里出错了。让错误行的结果为#VALUE!，最后汇总的结果也是#VALUE!，这样你就很容易知道有数据行错误，再去找就容易找到了，反之，你根本就不会想到会有数据出错，简而言之，让YJX = 1 / 0就是给自己一个发现错误的提示。

那为什么又要Exit Function，前面已经说过了，不退出的话，程序会接着执行后面的操作，这样会加重系统运行的负担，也耽误时间。

If…Then…Else是经常用到的条件判断语句，必须熟练运用。

若要把该语句内容写成一行时，也可以这么写：

If IsMissing(C) = False And C < 0 Then YJX 1 / 0: Exit Sub Else YJX = "正确"

:表示将前后两个语句合并写在一行时的分隔符，多个语句如此操作时也一样。

以上YJX = "正确"(结果2)只是为了完整表现If…Then…Else语句而特意添加的，如果不需要结果2，可以省略：

If IsMissing(C) = False And C < 0 Then '如果 条件符合 那么

YJX 1 / 0 ' 结果1

Exit Sub

End If '结束

若要把该语句内容写成一行时，也可以这么写：

If IsMissing(C) = False And C < 0 Then YJX 1 / 0: Exit Function

对长宽高三个参数都依次检查完成后，我还要对变量JG(结果样式)进行检查。我们前面约定了，当JG=0时输出公式结果，JG=1时输出公式，但如果我们代入的参数是2或其他整数呢？那么程序也不知道该怎么办了，只好等于0，这样一来，结果仍是错误的，所以，我们仍然要检查变量JG的错误：

If JG <> 0 And JG <> 1 Then YJX = 1 / 0: Exit Function

如此，本节的代码如下：

Function YJX(Optional C As Single, Optional K As Single, Optional G As Single, Optional JG As Integer = 0)

Dim GS

If IsMissing(C) = False And C < 0 Then YJX = 1 / 0: Exit Function

If IsMissing(K) = False And K < 0 Then YJX = 1 / 0: Exit Function

If IsMissing(G) = False And G < 0 Then YJX = 1 / 0: Exit Function

If JG <> 0 And JG <> 1 Then YJX = 1 / 0: Exit Function

…

End Function

⑤可选参数的判断及计算过程

计算时，我们必须要考虑可选参数对计算的影响，因为有可选参数与没有可选参数会影响到我们实际的计算需要。

因为我们已经设置了Optional JG As Integer = 0，即无论我们在工作表中写不写这个参数，它实际都存在，我们只是需要判断它是0还是1即可。

而高却可能是不存在的，所以我们现在只需要判断参数G是否存在就可以了：

If IsMissing(G) Then

GS = C & "*" & K

Else

GS = C & "*" & K & "*" & G

End If

说明：

如果这个函数只需要输出公式的结果（数值），那我们可以不需要GS变量，代码可以直接写为：

If IsMissing(G) Then

YJX = C * K

Else

YJX = C * K * G

End If

就因为我们还想着要输出计算公式，所以，要先用变量GS来“装载”计算公式，无论最终的计算公式是什么，我们在最后直接处理这个GS的内容就可以得到结果了。

& 是连接符，表示把两个内容前后连接在一起。比如：3 & "*" & 4，表示“3*4”，如果是3 * 4就表示其计算结果12了；变量在和文本连接时，文本需要用双引号""括起来。

如此，本节的代码如下：

Function YJX(C As Single, Optional K As Single, Optional G As Single, Optional JG As Integer = 0)

Dim GS

If IsMissing(G) Then

GS = C & "*" & K

Else

GS = C & "*" & K & "*" & G

End If

过程代码

End Function

⑥输出结果

现在，我们有了计算公式，下一步就是根据实际需要来处理这个公式内容了：

If JG = 0 Then

YJX = Evaluate("=" & GS)

ElseIf JG = 1 Then

YJX = GS

End If

说明：

以上代码表示，当JG=0时，函数输出公式的计算结果（数值），当JG=1时，直接输出公式。

Evaluate()是宏表函数，其作用是返回一个计算公式的结果，注意其参数为"=" & 公式。

如此，全部的函数代码就完成了：

Function YJX(Optional C As Single, Optional K As Single, Optional G As Single, Optional JG As Integer = 0)

Dim GS

If IsMissing(C) = False And C < 0 Then YJX = 1 / 0: Exit Function

If IsMissing(K) = False And K < 0 Then YJX = 1 / 0: Exit Function

If IsMissing(G) = False And G < 0 Then YJX = 1 / 0: Exit Function

If JG <> 0 And JG <> 1 Then YJX = 1 / 0: Exit Function

If IsMissing(G) Then

GS = C & "*" & K

Else

GS = C & "*" & K & "*" & G

End If

If JG = 0 Then

YJX = Evaluate("=" & GS)

ElseIf JG = 1 Then

YJX = GS

End If

End Function

⑦调试

下面，我们回到工作表中，测试一下这个函数的效果。

为什么会发生这种情况呢？

原来，在D2和E2单元格的公式中，我们引用了C2（高）这个参数，而C2的内容是空，VBA认为空单元格的值为0，于是，这个公式的实际内容其实成了“=3*4*0”。

如果我们把D2单元格的公式改为“=YJX(A2,B2)”倒是也能计算出结果来，但D3单元格的公式却必须为“=YJX(A3,B3,C3)”，如此，我们就不能使用工作表的拖拽功能了，这样使用起来，就非常的麻烦，所以，我们即然是在编写VBA的自定义函数，就应该考虑到应用的对象是工作表，参数可能是引用单元格的特殊性。

所以，我们需要把代码修改为：

If IsMissing(G) Then

GS = C & "*" & K

Else

GS = C & "*" & K & "*" & IIf(G = 0, 1, G)

End If

说明：

IIf()为VB函数，与工作表函数IF()类似，它就相当于简单版的If…Then…Else语句。

这里把判断参数G，当单元格为空时（即G=0），我们就让它等于1，因为任何数值乘以1都等于那个数值，如果单元格有数值，再乘以那个数值。

下面，我们再来看看效果。

这次，计算结果完全正确，但是…

D2单元格的计算公式却为“3*4*1”，可实际C2单元格并没有内容，看来还得修改一下： If IsMissing(G) Then

JX01:

GS = C & "*" & K

Else

If G = 0 Then GoTo JX01

GS = C & "*" & K & "*" & G

End If

这次，增加了一个判断，当单元格为空时（即G=0），程序按没参数G来编写公式。

这里，GoTo 语句的作用是让程序执行到这里时，直接跳到指定的程序标签处。那么，过程中必须存在这样一个标签，标签命名规则与变量相同，且以:结束，:后面不能跟有其他代码，否则那就成两个相连的语句了，而不是标签。

好，我们再来看看效果：

完全符合最初的要求，最后的代码如下：

Function YJX(Optional C As Single, Optional K As Single, Optional G As Single, Optional JG As Integer = 0)

Dim GS

If IsMissing(C) = False And C < 0 Then YJX = 1 / 0: Exit Function

If IsMissing(K) = False And K < 0 Then YJX = 1 / 0: Exit Function

If IsMissing(G) = False And G < 0 Then YJX = 1 / 0: Exit Function

If JG <> 0 And JG <> 1 Then YJX = 1 / 0: Exit Function

If IsMissing(G) Then

JX01:

GS = C & "*" & K

Else

If G = 0 Then GoTo JX01

GS = C & "*" & K & "*" & G

End If

If JG = 0 Then

YJX = Evaluate("=" & GS)

ElseIf JG = 1 Then

YJX = GS

End If

End Function

⑧功能拓展

虽然上面的结果达到了目的，但这样就不会有问题了么？不，其实我们在实际使用过程中，还会经常遇到象这样的情况：

从上面来看，不光是变量G(高)可能不存在，连变量C(长)和变量K(宽)也有可能是不存在的，所以，我们还需要进一步的完善。

既然变量C和变量K也可能不存在，那么，变量C和变量K就都得设为可选参数，如此，从头开始修改：

Function YJX(Optional C As Single, Optional K As Single, Optional G As Single, Optional JG As Integer = 0)

然后把先前对可选参数是否存在的判断修改为判断变量是否=0，即判断单元格是否为空。

GS = Iif(C > 0, C, “”) & _

Iif(C > 0 And (K > 0 Or G > 0), “*”, “”) & _

Iif(K > 0, K, “”) & _

Iif(K > 0 And G > 0, “*”, “”) & _

Iif(G > 0, G, “”)

说明：

_ 为换行符，当一行的内容太长时，可以使用 _ 换行。

最后再检查一下效果：

好，完全符合我们的要求。

全部的代码如下：

Function YJX(Optional C As Single, Optional K As Single, Optional G As Single, Optional JG As Integer = 0)

Dim GS

If IsMissing(C) = False And C < 0 Then YJX = 1 / 0: Exit Function

If IsMissing(K) = False And K < 0 Then YJX = 1 / 0: Exit Function

If IsMissing(G) = False And G < 0 Then YJX = 1 / 0: Exit Function

If JG <> 0 And JG <> 1 Then YJX = 1 / 0: Exit Function

GS = IIf(C > 0, C, "") & _

IIf(C > 0 And (K > 0 Or G > 0), "*", "") & _

IIf(K > 0, K, "") & _

IIf(K > 0 And G > 0, "*", "") & _

IIf(G > 0, G, "")

If JG = 0 Then

YJX = Evaluate("=" & GS)

ElseIf JG = 1 Then

YJX = GS

End If

End Function

⑨最终修改

其实我们从上图还发现了一个不完善的地方，第6行的参数宽为0，但这个0是写在单元格里的，并不是单元格为空，这有可能是手误，比如将10打成0了，而现在的代码是不能发现这种错误的，因为单元格为空，且参数的数据类型为Single（数值），不管单元格是空还是0，它都会自动附值为0，这也是VBA与VB的差别所在。但我们又想发现这种错误，那只有重新定义参数的数据类型,由此可见，声明变量的数据类型会对数据处理的影响有多大。

重新修改的代码如下：

Function YJXR(Optional C As Range, Optional K As Range, Optional G As Range, Optional JG As Integer = 0)

Dim GS

If JG <> 0 And JG <> 1 Then YJXR = 1 / 0: Exit Function

If IsMissing(C) = False Then

If YZS(C) <> -3 And YZS(C) <= 0 Then YJXR = 1 / 0: Exit Function If YZS(C) > 0 Then GS = C

End If

If IsMissing(K) = False Then

If YZS(K) <> -3 And YZS(K) <= 0 Then YJXR = 1 / 0: Exit Function If YZS(K) > 0 Then

If Len(GS) > 0 Then GS = GS & "*" & K Else GS = K

End If

End If

If IsMissing(G) = False Then

If YZS(G) <> -3 And YZS(G) <= 0 Then YJXR = 1 / 0: Exit Function If YZS(G) > 0 Then

If Len(GS) > 0 Then GS = GS & "*" & G Else GS = G

End If

End If

If JG = 0 Then

YJXR = Evaluate("=" & GS)

ElseIf JG = 1 Then

YJXR = GS

End If

End Function

修改说明：

本次将函数名修改为YJXR，区别前面那个函数YJX，意思为这个函数只能用于计算单元格，而前面那个函数可以在工作表和程序内部使用，但它不能判断单元格为空的情况。

参数重新定义为Range数据类型，这个数据类型在前面的表格里录入，因为它是专为EXCEL VBA定制的一个数据类型，只能用于处理单元格变量。这也就是为什么这个函数要分成两种的原因，由于这是程序语言本身的限制所决定，仅靠代码是无法兼容的，所以，具体使用时，可以根据不同的需要来分别使用这两个函数。

本次将检查错误和编写计算公式（蓝粗字）的步骤合并起来，当检查一个参数没有错误时，就直接写出相应的计算公式，而不必等到最后再统一编写了。至于计算公式为什么这么写，可以根据我前面所讲的附值规则思考一下。

Len()是VB函数，作用是返回一个字符串的字符数量，当这个字符串没有内容，即它是空的时候，结果=0。

YZS()是我编写的另一个自定义函数，用来判断数据是哪种类型的，正面我一并附上这个函数的代码，使用方法可以参考它的说明。

'■■■■■■YZS（字符串，类型判断）函数■■■■■■

'判断字符串的数值类型

'字符串为真假值——返回-6

'字符串为错误值——返回-5

'字符串为文本值——返回-4

'字符串为 空 ——返回-3

'字符串为负小数——返回-2

'字符串为负整数——返回-1

'字符串为 0 ——返回 0

'字符串为正整数——返回 1

'字符串为正小数——返回 2

'类型判断为0，字符串为整数——返回 True

'类型判断为1，字符串为奇数——返回 True

'类型判断为2，字符串为偶数——返回 True'

'修改日期：2017-11-12 增加判断真假值=-6

Function YZS(Vax, Optional Lax)

If IsMissing(Lax) Then

If IsError(Vax) Then YZS = -5: Exit Function '数据为错误值

If Len(Vax) = 0 Then YZS = -3: Exit Function '数据为空

If IsNumeric(Vax) = False Then YZS = -4: Exit Function '数据为文本值 If Val(Vax) = 0 And Left(Vax, 1) <> "0" Then YZS = -6: Exit Function '数据为真假值

If Vax = 0 Then YZS = 0: Exit Function

If InStr(Vax, ".") > 0 Then

If Vax > 0 Then YZS = 2 Else YZS = -2 '数据为小数

Else

If Vax > 0 Then YZS = 1 Else YZS = -1 '数据为整数

End If

Else

If Lax = 0 Or Lax = 1 Or Lax = 2 Then

If IsNumeric(Vax) = False Then YZS = False: Exit Function

If Len(Vax) = 0 Then YZS = False: Exit Function

If InStr(Vax, ".") > 0 Then YZS = False: Exit Function

If Lax = 0 Then '判断数值是否为整数

YZS = True

ElseIf Lax = 1 Then '判断数值是否为奇数

If InStr(Vax / 2, ".") > 0 Then YZS = True Else YZS = False ElseIf Lax = 2 Then '判断数值是否为偶数

If InStr(Vax / 2, ".") > 0 Then YZS = False Else YZS = True End If

End If

End If

End Function

最后再次检查一下使用效果：正确！