ARM启动代码详细注释

ARM启动代码详细注释

syd168 2009-07-23

2410Init.s包括了板子上电后的初始化过程，具体有以下几个步骤：

1.屏蔽所有中断，关看门狗。

2.根据工作频率设置PLL寄存器

3.初始化存储控制相关寄存器

4.初始化各模式下的栈指针

5.设置缺省中断处理函数

6.将数据段拷贝到RAM中，将零初始化数据段清零

7.跳转到C语言Main入口函数中

;=========================================

; NAME: 2410INIT.S

; DESC: C start up codes

; Configure memory, ISR ,stacks

; Initialize C-variables

; HISTORY:

; 2002.02.25:kwtark: ver 0.0

; 2002.03.20:purnnamu: Add some functions for testing STOP,POWER_OFF mode

; 2002.04.10:SJS:sub interrupt disable 0x3ff -> 0x7ff

;=========================================

GET option.s ;GET相当INCLUDE 将一个源文件包含到当前源文件，这里表示包含option.s，并在当前位置进行汇编

GET memcfg.s

GET 2410addr.s

BIT_SELFREFRESH EQU (1<<22)

;SDRAM/DRAM 刷新控制器bit22 REFMD位0:CBR/AUTO REFRESH 1:SHIF REFRESH

;下面是对arm处理器模式寄存器对应值的常数定义，arm处理器中有一个CPSR程序状态寄存器，后五位决定目前的处理器模式。;Pre-defined constants ;PSR 模式位

USERMODE EQU 0x10 ;用户模式

FIQMODE EQU 0x11 ;FIQ快速中断模式

IRQMODE EQU 0x12 ;中断模式

SVCMODE EQU 0x13 ;超级用户模式

ABORTMODE EQU 0x17 ;中止模式

UNDEFMODE EQU 0x1b ;未定义指令模式

MODEMASK EQU 0x1f ;系统模式

NOINT EQU 0xc0 ;禁止IRQ和FIQ中断

在option.s中, _STACK_BASEADDRESS EQU (SDRAM_END-0x8000) ;0x33ff8000

;;定义各模式堆栈地址_STACK_BASEADDRESS

UserStack EQU (_STACK_BASEADDRESS-0x3800) ;0x33ff4800 ~ ; 用户模式堆栈

SVCStack EQU (_STACK_BASEADDRESS-0x2800) ;0x33ff5800 ~0x3ff47ff ; 超级用户模式堆栈4k

UndefStack EQU (_STACK_BASEADDRESS-0x2400) ;0x33ff5c00 ~0x3ff57ff ; 未定义指令模式堆栈1k

AbortStack EQU (_STACK_BASEADDRESS-0x2000) ;0x33ff6000 ~0x3ff5bff ; 中止模式堆栈1k

IRQStack EQU (_STACK_BASEADDRESS-0x1000) ;0x33ff7000 ~0x3ff5fff ; 中断模式堆栈4k

FIQStack EQU (_STACK_BASEADDRESS-0x0) ;0x33ff8000 ~0x33ff6fff ; 快速中断模式堆栈4k

;arm处理器有两种工作状态

;1.arm:32位这种工作状态下执行字对齐的arm指令

;2.Thumb:16位这种工作状;态执行半字对齐的Thumb指令

;因为处理器分为16位32位两种工作状态程序的编译器也是分16位和32两种编译方式

;所以下面的程序用于根据处理器工作状态确定编译器编译方式

;code16伪指令指示汇编编译器，后面的指令为16位的thumb指令

;code32伪指令指示汇编编译器，后面的指令为32位的arm指令

;这段是为了统一目前的处理器工作状态和软件编译方式（16位编译环境使用tasm.exe编译）

;===========================================================================================

;Check if tasm.exe(armasm -16 ...@ADS 1.0) is used. 检查是否是用tasm.exe进行16位编译

GBLL THUMBCODE ;声明一个全局变量并初始化为{FALSE}

[ {CONFIG} = 16 ;if config=16这里表示用16位编译方式THUMBCODE SETL {TRUE} ;SETL 给全局变量赋值，;设置THUMBCODE 为true CODE32 ;转入32位编译模式

| ; | 等同ELSE

THUMBCODE SETL {FALSE} ;设置THUMBCODE 为false

] ; ] 等同ENDIF

;========================================================================================== MACRO ;MACRO 定义宏

MOV_PC_LR ;宏名MOV_PC_LR

[ THUMBCODE ;if THUMBCODE=true

bx lr ;THUMBCODE 模式上返回ARM状态

| ;else

mov pc,lr ;ARM状态下返回

] ;end if

MEND ;宏结束

;================================================================

MACRO ;宏定义开始

MOVEQ_PC_LR ;宏名为MOVEQ_PC_LR

[ THUMBCODE ;if THUMBCODE=true

bxeq lr ;EQ 相等则跳转回ARM状态

| ;else

moveq pc,lr ;????

] ;end if

MEND ;宏结束

;==================================================================

;注意下面这段程序是个宏定义

;下面包含的HandlerXXX HANDLER HandleXXX将都被下面这段程序展开

;这段程序用于把中断服务程序的首地址装载到pc中，有人称之为“加载程序”。

;本初始化程序定义了一个数据区（在文件最后），34个字空间，存放相应中断服务程序的首地址。每个字，即4字节

;空间都有一个标号，以Handle***命名。

;在向量中断模式下使用“加载程序”来执行中断服务程序。

;这里就必须讲一下向量中断模式和非向量中断模式的概念

;向量中断模式是当cpu读取位于0x18处的IRQ中断指令的时候，系统自动读取对应于该中断源确定地址上的指令取代0x18处的指令，;通过跳转指令系统就直接跳转到对应地址

;函数中节省了中断处理时间提高了中断处理速度标例如ADC中断的向量地址为0xC0,则在0xC0处放如下代码：

;ldr PC,=HandlerADC 当ADC中断产生的时候系统会自动跳转到HandlerADC函数中

;非向量中断模式处理方式是一种传统的中断处理方法，当系统产生中断的时候，系统将interrupt pending寄存器中对应标志位置位

;然后跳转到位于0x18处的统一中断;函数中

;该函数通过读取interrupt pending寄存器中对应标志位来判断中断源，并根据优先级关系再跳到;对应中断源的处理代码中

;大致作用是把宏的第一个参数$HandlerLabel转变为一个标号，然后让程序跳转到第二个参数$HandleLabel(为一个地址)对应的值的地址去。

下面一句一句分析一下，为了便于分析，

假设sp = 0x33ff8000，$HandleLabel = 0x33ffff00, [0x33ffff00] = 0x10000000，r0 = 0x56001234：

$HandlerLabel HANDLER $HandleLabel 说明宏名字叫HANDLER ,有一个参数$HandlerLabel ，它定义了一个标号

sub sp,sp,#4 把栈顶指针减4，留出一个字的空间（用于保存跳转地址的值）,sp=0x33ff7ffc

stmfd sp!,{r0} 首先把sp减 4 (sp=0x33ff7ff8)，然后把将要使用的r0入栈，此时[0x33ff7ff8]=0x56001234

ldr r0,=$HandleLabel 给寄存器r0赋值，r0=0x33ffff00

ldr r0,[r0] 给寄存器r0赋值，r0=0x10000000

str r0,[sp,#4] 把寄存器r0保存到0x33ff7ffc (sp=0x33ff7ff8+4)，此时[0x33ff7ffc] = 0x10000000

ldmfd sp!,{r0,pc} 把栈顶的两个字弹出，分别保存到r0、pc，此时sp=0x33ff8000，r0=0x56001234，pc=0x10000000 ，通过比较不难发现，sp和r0在执行前后都没有变化，程序就跳转到0x10000000处执行

;所以，通过上面的分析可以看出，$HandlerLabel HANDLER $HandleLabel是让PC跳转到$HandleLabel中存放的地址执行。

MACRO ;宏定义

$HandlerLabel HANDLER $HandleLabel

;$HandlerLabel 行号展开时可替换成相应的符号

;HANDLER 宏名

;$HandleLabel 宏的形参

$HandlerLabel ; 展开时可替换成相应的符号

sub sp,sp,#4 ;sp-sp-4,空出的空间用于存放跳转地址假如sp原来为0x100，则现在sp为0x96

stmfd sp!,{r0} ;sp=sp-4,并将r0入栈，现在sp=0x92 r0存入0x96

ldr r0,=$HandleLabel ;获取存放跳转地址的标号HandleLabel到r0,假如HandleLabel为0x1000，则现在r0为0x1000

ldr r0,[r0] ;将HandleLabel中存放的跳转地址送给r0，r0为0x1000中的值，假如为0x3000

str r0,[sp,#4] ;将r0存放到sp+4的地方，

ldmfd sp!,{r0,pc} ;将中断函数首地址出栈，放入程序指针中，系统将跳转到对应中断处理函数

MEND ;宏定义结束

;==================================================================

;一个ARM由RO,RW,ZI三个段组成，其中RO(只读)为代码段，RW(读写)是已经初始化的全局变量，ZI是未初始化的全局变量

;对应于GNU工具的概念是TEXT，DATA，BSS

;bootloader要将RW段复制到RAM中，并将ZI段清零编译器使用下列方式来记录各段的起始和结束地址

; |Image$$RO$$Base| ; RO段起始地址

; |Image$$RO$$Limit| ; RO段结束地址加 1

; |Image$$RW$$Base| ; RW段起始地址

; |Image$$RW$$Limit| ; RW段结束地址加 1

; |Image$$ZI$$Base| ; ZI段起始地址

; |Image$$ZI$$Limit| ; ZI段结束地址加 1

;这些标号的值是通过编译器设定来确定的如编译软件中对ro-base和rw-base的设定分别为：ro-base=0xc000000 rw-base=0xc5f0000

IMPORT |Image$$RO$$Limit| ; End of ROM code (=start of ROM data)

IMPORT |Image$$RW$$Base| ; Base of RAM to initialise

IMPORT |Image$$ZI$$Base| ; Base and limit of area

IMPORT |Image$$ZI$$Limit| ; to zero initialise

;下面语句是声明引用外部函数

IMPORT Main ;C程序(在2410test.c) The main entry of mon program

;===================================================

AREA Init,CODE,READONLY ;Init 初始化程序

;异常中断矢量表（每个表项占4个字节）

;下面是中断向量表一旦系统运行时就可能有中断发生

;即使移植了操作系统(如linux)，处理器已经把控制权交给了操作系统，但如果发生中断，处理器还是会跳转到从0x0开始的;中断向量表中某个中断表项（依据中断类型）开始执行。具体中断向量布局请参考s3c44b0 spec

;例如adc中断向量为0x000000c0下面对应表中第49项位置向量地址0x0+4*(49-1)=0x000000c0

;==========================================================

;板子上电和复位后程序开始从位于0x0处开始执行，硬件刚刚上电复位后程序从这里开始执行跳转到标为ResetHandler处执行

;DCD用于分配一段字内存单片，并用后面的伪指令初始化，分配字节由expr 个数决定

ENTRY ;程序入口

;1)The code, which converts to Big-endian, should be in little endian code.

;2)The following little endian code will be compiled in Big-Endian mode. The code byte order should be changed as the memory bus width.

;3)The pseudo instruction,DCD can't be used here because the linker generates error.

ASSERT :DEF:ENDIAN_CHANGE ;ASSERT 断言错误伪指令，这里表示是否定义过ENDIAN_CHANGE

[ ENDIAN_CHANGE ;如果定义了ENDIAN_CHANGE

ASSERT :DEF:ENTRY_BUS_WIDTH ;这里表示是否定义过ENTRY_BUS_WIDTH

[ ENTRY_BUS_WIDTH=32 ;if ENTRY_BUS_WIDTH=32

b ChangeBigEndian ;跳转到ChangeBigEndian （见下面红色代码），执行DCD 0xea000007 改变大小端数据模式

] ;end if

[ ENTRY_BUS_WIDTH=16 ;if ENTRY_BUS_WIDTH=16

andeq r14,r7,r0,lsl #20 ;当标志状态寄存器CPSR的Z位=1时,r14=r7+r0逻辑左移20位，执行DCD 0x0007ea00改变大小端模式] ;end if

[ ENTRY_BUS_WIDTH=8 ;if ENTRY_BUS_WIDTH=8

streq r0,[r0,-r10,ror #1] ;当标志状态寄存器CPSR的Z位=1时…，执行DCD 0x070000ea 改变大小端模式

] ;end if

| ;ELSE 即如果没定义ENDIAN_CHANGE

b ResetHandler ;复位处理模式

]

b HandlerUndef ;handler for Undefined mode 处理为定义模式

b HandlerSWI ;handler for SWI interrupt 处理软中断模式

b HandlerPabort ;handler for PAbort 处理终止程序访问终止模式

b HandlerDabort ;handler for DAbort 处理数据访问终止模式

b . ;reserved 保留，"."代表指令的地址，即表示进行死循环

b HandlerIRQ ;handler for IRQ interrupt 处理中断模式

b HandlerFIQ ;handler for FIQ interrupt 处理快速中断模式

;@0x20 "@" 存储区位置计数器的当前值

b EnterPWDN ;进入掉电模式，见下面的标号

ChangeBigEndian ;改变大小端数据模式

;@0x24

;=========================下面是大小端格式内存设置？？？=================== [ ENTRY_BUS_WIDTH=32 ;if ENTRY_BUS_WIDTH=32

DCD 0xee110f10 ;0xee110f10 => mrc p15,0,r0,c1,c0,0

DCD 0xe3800080 ;0xe3800080 => orr r0,r0,#0x80; //Big-endian

DCD 0xee010f10 ;0xee010f10 => mcr p15,0,r0,c1,c0,0

]

[ ENTRY_BUS_WIDTH=16 ;if ENTRY_BUS_WIDTH=16

DCD 0x0f10ee11

DCD 0x0080e380

DCD 0x0f10ee01

]

[ ENTRY_BUS_WIDTH=8 ;if ENTRY_BUS_WIDTH=8

DCD 0x100f11ee

DCD 0x800080e3

DCD 0x100f01ee

]

DCD 0xffffffff ;swinv 0xffffff is similar with NOP and run well in both endian mode.

DCD 0xffffffff

DCD 0xffffffff

DCD 0xffffffff

DCD 0xffffffff

b ResetHandler ;复位处理程式

;进入掉电模式功能

; 1. SDRAM 必须在自刷新模式.

; 2. 所有中断必须屏蔽for SDRAM/DRAM self-refresh.

; 3. LCD 关闭for SDRAM/DRAM self-refresh.

; 4. The I-cache 可能需要开启.

; 5. The location of the following code may have not to be changed.

;void EnterPWDN(int CLKCON); ;进入掉电模式

EnterPWDN

mov r2,r0 ;r2=rCLKCON CLKCON[3] power_off bit 0:disable 1:transition to power_off mode

tst r0,#0x8 ;判断POWER_OFF 是否为0 r0和#0X8相与更新CPSR 位

bne ENTER_POWER_OFF ;NE 不相等(则表示power_off不为O) 标志位Z=0

ENTER_STOP ;不进入掉电模式

ldr r0,=REFRESH ;0x48000024 ;DRAM/SDRAM refresh DRAM/SDRAM 刷新控制器

ldr r3,[r0] ;r3=rREFRESH

mov r1, r3 ;r1=r3

(1<<22) ;bit22 TREFMD位0:CBR/AUTO REFRESH 1:SHIF REFRESH orr r1, r1, #BIT_SELFREFRESH ;BIT_SELFREFRESH EQU

str r1, [r0] ;R1->[R0] Enable SDRAM self-refresh

mov r1,#16 ;延时wait until self-refresh is issued. may not be needed.

0 subs r1,r1,#1 ;0为局部标号（延时）

bne %B0 ; % 表示局部标号引用B:指示编译器向后搜索0为局部标号

ldr r0,=CLKCON ;enter STOP mode. CLKCON ;Clock generator control

str r2,[r0]

mov r1,#32

0 subs r1,r1,#1 ;1)延时wait until the STOP mode is in effect.

bne %B0 ;2) Or wait here until the CPU&Peripherals will be turned-off

; Entering POWER_OFF mode, only the reset by wake-up is available.

ldr r0,=REFRESH ;exit from SDRAM self refresh mode.

str r3,[r0]

MOV_PC_LR ;调用宏MOV_PC_LR

ENTER_POWER_OFF ;进入掉电模式

;NOTE.

;1) rGSTATUS3 should have the return address after wake-up from POWER_OFF mode.

ldr r0,=REFRESH

ldr r1,[r0] ;r1=rREFRESH

orr r1, r1, #BIT_SELFREFRESH

str r1, [r0] ;Enable SDRAM self-refresh

mov r1,#16 ;Wait until self-refresh is issued,which may not be needed.

0 subs r1,r1,#1 ;延时

bne %B0

ldr r1,=MISCCR ; ;Miscellaneous control

ldr r0,[r1]

orr r0,r0,#(7<<17) ;Make sure that SCLK0:SCLK->0, SCLK1:SCLK->0, SCKE=L during boot-up str r0,[r1]

ldr r0,=CLKCON

str r2,[r0]

b . ;CPU will die here. "."当前指令的地址CPU死在这

WAKEUP_POWER_OFF ;掉电唤醒

;Release SCLKn after wake-up from the POWER_OFF mode.

ldr r1,=MISCCR ;Miscellaneous control

ldr r0,[r1]

bic r0,r0,#(7<<17) ;SCLK0:0->SCLK, SCLK1:0->SCLK, SCKE:L->H

str r0,[r1]

;Set memory control registers

ldr r0,=SMRDATA

ldr r1,=BWSCON ;BWSCON Address 起始位置依次为BANKCON0 BANKCON1 BANKCON2 ........

add r2, r0, #52 ;End address of SMRDATA

ldr r3, [r0], #4 ;读取R0地址的数据到R3 R0=R0+4 读取SMRDATA 数组(BWSCON BANKCON0 ....)的值

str r3, [r1], #4 ;读取R3的数据到R1地址内存中R1=R1+4 赋给BWSON BANKCON0 ....寄存器

cmp r2, r0

bne %B0 ;判断是否赋完值

mov r1,#256

0 subs r1,r1,#1 ;1) wait until the SelfRefresh is released.

bne %B0 ;延时

ldr r1,=GSTATUS3 ;GSTATUS3 has the start address just after POWER_OFF wake-up

ldr r0,[r1] ;Saved data0(32-bit) before entering POWER_OFF mode

mov pc,r0

LTORG ;文字池

;下面是具体的中断处理函数跳转的宏，通过上面的$HandlerLabel的宏定义展开后跳转到对应的中断处理;函数（对于向量中断）

HandlerFIQ HANDLER HandleFIQ ;调用宏HANDLER

HandlerIRQ HANDLER HandleIRQ ;HandlerIRQ 行号HANDLER 宏名HandleIRQ 导入的形参

HandlerUndef HANDLER HandleUndef

HandlerSWI HANDLER HandleSWI

HandlerDabort HANDLER HandleDabort

HandlerPabort HANDLER HandlePabort

;下面这段程序是用来处理非向量中断，具体判断I_ISPR中各位是否置 1 ，置1表示目前此中断等待响应（每次只能有一位置1），;从最高优先级中断位开始判断，检测到等待服务中断就将pc置为中断服务函数首地址

IsrIRQ ;IRQ模式中断（片内外设中断引脚中断）

sub sp,sp,#4 ;预留pc返回指针的存储位置

stmfd sp!,{r8-r9} ;将R8~R9 放入堆栈

ldr r9,=INTOFFSET ;中断请求源偏移寄存器

ldr r9,[r9]

ldr r8,=HandleEINT0 ;IRQ 中断首址

add r8,r8,r9,lsl #2 ;r8=r8+ r9<<2 r9<<2(乘4)

ldr r8,[r8] ;取[r8]地址的数据放入R8

str r8,[sp,#8] ;将R8中的数据放入[sp+8]的地址中

ldmfd sp!,{r8-r9,pc} ;将堆栈内空恢复到R8 R9 PC

;===================================

; ENTRY

;===================================

;扳子上电和复位后程序开始从位于0x0执行，b ResetHandler 程序从跳转到这里执行

;板子上电复位后执行几个步骤。这里通过标号在注释中加1，2，3....标示标号表示执行顺序

;1.禁止看门狗屏蔽所有中断

ResetHandler ;复位处理程式

ldr r0,=WTCON ;关闭看门狗watch dog disable

ldr r1,=0x0

str r1,[r0] ;r1->[r0] 禁止看门狗

ldr r0,=INTMSK

ldr r1,=0xffffffff ;all interrupt disable

str r1,[r0] ;r1->[r0] 禁止所有中断

ldr r0,=INTSUBMSK

ldr r1,=0x7ff ;all sub interrupt disable, 2002/04/10 str r1,[r0]

[ {FALSE} ;fi

; rGPFDAT = (rGPFDAT & ~(0xf<<4)) | ((~data & 0xf)<<4);

; Led_Display

ldr r0,=GPFCON ;F口控制寄存器

ldr r1,=0x5500 ;GPF7-GPF6 output GPF5-GPF0 input str r1,[r0]

ldr r0,=GPFDAT ;F口数据寄存器

ldr r1,=0x10

str r1,[r0]

]

;2.根据工作频率设置pll

;这里介绍一下计算公式

;Fpllo=(m*Fin)/(p*2^s)

;m=MDIV+8,p=PDIV+2,s=SDIV

;Fpllo必须大于20Mhz小于66Mhz

;Fpllo*2^s必须小于170Mhz

;如下面的PLLCON设定中的M_DIV P_DIV S_DIV是取自option.h中;#elif (MCLK==40000000)

;#define PLL_M (0x48)

;#define PLL_P (0x3)

;#define PLL_S (0x2)

;所以m=MDIV+8=80,p=PDIV+2=5,s=SDIV=2

;硬件使用晶振为10Mhz,即Fin=10Mhz

;Fpllo=80*10/5*2^2=40Mhz

;To reduce PLL lock time, adjust the LOCKTIME register.

ldr r0,=LOCKTIME

ldr r1,=0xffffff

str r1,[r0]

[ PLL_ON_START

;Configure MPLL

ldr r0,=MPLLCON

ldr r1,=((M_MDIV<<12)+(M_PDIV<<4)+M_SDIV) ;Fin=12MHz,Fout=50MHz str r1,[r0]

]

;Check if the boot is caused by the wake-up from POWER_OFF mode.

ldr r1,=GSTATUS2 ; GSTATUS2 复位状态寄存器

ldr r0,[r1]

tst r0,#0x2 ;判断R0 的第二位是否为0

;In case of the wake-up from POWER_OFF mode, go to POWER_OFF_WAKEUP handler.

bne WAKEUP_POWER_OFF

EXPORT StartPointAfterPowerOffWakeUp ;声明全局函数

StartPointAfterPowerOffWakeUp

;3.置存储相关寄存器的程序

;这是设置SDRAM,flash ROM 存储器连接和工作时序的程序,片选定义的程序

;SMRDATA map在下面的程序中定义

;SMRDATA中涉及的值请参考memcfg.s程序

;具体寄存器各位含义请参考s3c44b0 spec

;Set memory control registers

ldr r0,=SMRDATA

ldr r1,=BWSCON ;BWSCON Address ;BWSCON Address 起始位置依次为BANKCON0 BANKCON1 BANKCON2 ........

add r2, r0, #52 ;End address of SMRDATA

ldr r3, [r0], #4 ;;读取R0地址的数据到R3 R0=R0+4 读取SMRDATA 数组(BWSCON BANKCON0 ....)的值str r3, [r1], #4 ;读取R3的数据到R1地址内存中R1=R1+4 赋给BWSON BANKCON0 ....寄存器

cmp r2, r0

bne %B0

;Initialize stacks

bl InitStacks ;初始化堆栈

;4.设置缺省中断处理函数

; Setup IRQ handler

ldr r0,=HandleIRQ ;This routine is needed

ldr r1,=IsrIRQ ;if there isn't 'subs pc,lr,#4' at 0x18, 0x1c

str r1,[r0]

;5.复制和初始化RW和ZI区域

;Copy and paste RW data/zero initialized data

ldr r0, =|Image$$RO$$Limit| ; Get pointer to ROM data read only code

ldr r1, =|Image$$RW$$Base| ; and RAM copy readwriter data

ldr r3, =|Image$$ZI$$Base| ;zero initializ data

;6.将数据段拷贝到ram中将零初始化数据段清零跳入C语言的main函数执行到这步结束bootloader初步引导结束;Zero init base => top of initialised data

cmp r0, r1 ; Check that they are different

beq %F2 ;向前搜索->

1

cmp r1, r3 ; Copy init data R1与R3比较R1减R3

ldrcc r2, [r0], #4 ;--> LDRCC r2, [r0] + ADD r0, r0, #4 cc:无符号数小于

strcc r2, [r1], #4 ;--> STRCC r2, [r1] + ADD r1, r1, #4

bcc %B1 ;;向后搜索<-

2

ldr r1, =|Image$$ZI$$Limit| ; Top of zero init segment

mov r2, #0

3

cmp r3, r1 ; Zero init

strcc r2, [r3], #4

bcc %B3

[ :LNOT:THUMBCODE ;将THUMBCODE 做逻辑非操作

bl Main ; ;转入C程序Don't use main() because ......

b .

]

[ THUMBCODE ;for start-up code for Thumb mode

orr lr,pc,#1

bx lr

CODE16

bl Main ;;转入C程序Don't use main() because ......

b .

CODE32

]

;这是上面提到的对存储寄存器初始化的数据map

;function initializing stacks 初始化堆栈

InitStacks

;Don't use DRAM,such as stmfd,ldmfd......

;SVCstack is initialized before

;Under toolkit ver 2.5, 'msr cpsr,r1' can be used instead of 'msr cpsr_cxsf,r1'

mrs r0,cpsr ;r0<-cpsr

bic r0,r0,#MODEMASK ;MODEMASK=0x1f 清除CPSR中的PSR位（5bit) orr r1,r0,#UNDEFMODE|NOINT ;NOINT=0XC0 禁止IRQ和FIQ中断

msr cpsr_cxsf,r1 ;UndefMode cpsr_cxsf<-r1

ldr sp,=UndefStack

orr r1,r0,#ABORTMODE|NOINT

msr cpsr_cxsf,r1 ;AbortMode

ldr sp,=AbortStack

orr r1,r0,#IRQMODE|NOINT

msr cpsr_cxsf,r1 ;IRQMode

ldr sp,=IRQStack

orr r1,r0,#FIQMODE|NOINT

msr cpsr_cxsf,r1 ;FIQMode

ldr sp,=FIQStack

bic r0,r0,#MODEMASK|NOINT

orr r1,r0,#SVCMODE

msr cpsr_cxsf,r1 ;SVCMode

ldr sp,=SVCStack

;USER mode has not be initialized. 用户模式不初始化堆栈

mov pc,lr

;The LR register won't be valid if the current mode is not SVC mode.