sum函数超级技巧实例

1、对生产表大于110或者小于100的数据求和

公式：=SUM(((B2:B11<100)+(B2:B11>110))*B2:B11) 同时按［Ctrl+Shift+Enter］组合键

公式说明：

对于两个范围求和，即满足两个条件中任意一个条件都进行求和，这和同时满足两个条件才求和的公式思路不同。多个条件同时满足才求和需要用“*”连接所有条件，表示同时满足多条件，而在这对多个条件用“+”来连接，表示对于多条件中满足任意一个条件就可以进行求和。

使用注意：

1、多条件满足任意条件即求和，在设置公式时对于所有条件需要用“+”连接，如本例中

“(B2:B11<100)+(B2:B11>110)”，然后对条件用括号括起来再与实际求和区相乘。如果缺少条件的外括号将得到错误结果。

2、如果不只两个条件，也用同样方式将所有条件罗列出来并相加。例如求区域中小于100或者等于100或者等于120的数据和，那么数组公式如下：

=SUM(((B2:B11<100)+(B2:B11=100)+(B2:B11=120))*B2:B11)

2、对生产表中大于100的产量进行求和（SUM）

在单元格D2中输入如下数组公式：

=SUM((B2:B11>100)*B2:B11) 同时按下【Ctrl+Shift+Enter】组合键，公式将返回B列中大于100的数据之和，结果如上图。

本公式为数组公式，可以对B2:B11区域中大于100的数据进行求和，而排除大于等于100的数据。输入公式时必须按【Ctrl+Shift+Enter】组合键结束，否则无法得到正确结果。

使用注意：

1、公式中“B2:B11>100”部分表示求和条件，后跟实际求和区域“B2:B11”。如果有多个条件，可一并罗列出来。例如求大于100且小于115的数据之和，公式如下：

=SUM((B2:B11>100)*(B2:B11<115)*B2:B11)

2、此数组公式只适用于单个区域求和，如果有多个区域，只能用多个SUM求和，然后相加。例如对B2:B11和D2:D12区域中大于100的数汇总，公式如下：

=SUM((B2:B11>100)*B2:B11)，SUM((D2:D11>100)*D2:D11)

3、对于SUM函数的数组公式，可以用SUMPRODUCT函数来代替，从而将数组公式转换成普通公式。例如本题中的公式改用SUMPRODUCT函数后，普通公式如下：

=SUMPRODUCT((B2:B11>100)*B2:B11)

提示：对区域中不等于某值的数汇总，可以使用不等号“<>”作为限制条件。

3、对三组生产数据求和（SUM）

在单元格H2中输入如下公式：

=SUM(B2:B7,D2:D7,F2:F7)

公式说明：

SUM函数用于对单元格区域的数据或者逻辑值、表达式进行求和，它有1～255个参数。在这主要对区域B2：B7、D2：D7、F2：F7三个参数代表的三个区域进行求和。鉴于本题的特殊性，公式也可以改为“=SUM(B2:F7)”，函数会忽略区域中的本文。

使用注意：

1、SUM函数有1～255个参数，参数可以是区域，也可以是表达式。如：

=SUM(A1，10*25，A3*8)

2、如果是文本型数字参数，SUM函数是可以直接求和的；如果是引用单元格中的文本型数字（单元格的数字前添加半角单引号“'”），则求和时将忽略。例如A1的值是“'10”，那么以下公式的结果大不相同。

=SUM(10,"10")——结果为20

=SUM(10,A1)——结果为10

3、如果一定要对单元格中文本型数字进行求和，可以将它转型成数值。转换方法包括多种：利用Value 转换、利用“--”转换和利用“*1”、“/1”方式转换。例如：

=SUM(10，VALUE(A1))

=SUM(10,--(A1))

=SUM(10,(A1)*1)

提示：在每个区域地址之前添加工作表名及“!”，如“Sheet2!B2:B7”。

4、对一车间男性职工的工资求和

公式：=SUM((B2:B10="一车间")*(C2:C10="男")*D2:D10) 同时按[Ctrl+Shift+Enter]组合键

公式说明：

本公式以B、C两列数据作为限制条件，对D列数据汇总。"(B2:B10="一车间")*(C2:C10="男")"表示同时满足此两个条件，如果还有更多条件，也可以同时罗列出来，利用“*”符号连接，然后再与求和区相乘，得到最后的汇总结果。

使用注意：

1、本例以不同的区域作为限制，条件区有两个，对第三区载进行求和。在设置公式时，三个区域的单元格个数必须一致。例如以下公式将产生错误结果。

=SUM((B2:B9="一车间")*(C2:C10="男")*D2:D10)

=SUM((B2:B10="一车间")*(C3:C10="男")*D2:D10)

2、多条件求和时，条件引用区域与求和区域可以在不同列，三个区域只需要宽度、高度一致即可。它们所在的列可以不同，起止行也可以不同，甚至三个区域可以分别位于不同的工作表中，仍然可以得到需要的结果。例如条件区在Sheet2工作表，求和区在当前，公式可以修改为：

=SUM((Sheet2!B2:B10="一车间")*(Sheet2!C2:C10="男")*D2:D10)

3、本公司可以用另一种简化写法，仍然可以返回正确结果。

=SUM((B2:B10&C2:C10="一车间男")*D2:D10)

5、对同一姓的职工工资求和

本题公式：=SUM((LEFT(A2:A10)="赵")*(C2:C10="女")*D2:D10) 同时按下[Ctrl+Shitf+Enter］组合键、

公式说明：

公式中首先用LEFT函数提取A列姓名第一个字符，如果第一字符是“赵”，那么连接第二个条件：性别为女，最后将限制条件与求和区相乘，得到最后汇总结果。

如果是姓名中包含“赵”而非首字符为“赵”，如姓名“陈文赵”，那么可以将LEFT函数改为FIND函数，公式如下：

=SUM(ISNUMBER(FIND("赵",A2:A10))*(C2:C10="女")*D2:D10)

使用注意：

1、LEFT函数用于职字符串左边指定位数的字符。本题中只取左边一位，故省略第二参数。如果取左边两位，如姓“欧阳”者，则用以下公式：

=SUM((LEFT(A2:A10，2)="欧阳")*(C2:C10="女")*D2:D10)

2、本题中仍然可以使用“&”连接符来缩短公式。

=SUM((LEFT(A2:A10)&C2:C10="赵女")*D2:D10)

数组中，逗号表示列（比如1，2，就表示一列中的一行，二行），分号表示行（比如1；2,就表示一行中的一列，二列），比如“=INDEX({1,2;3,4},0,2) 返回数组常量中第一行、第二列的值(2) ，返回数组常量中第二行、第二列的值(4) ”，引号“：”表示，星号“*”表示，

症状1：

打开任何EXCEL文件，都提示错误，要求发送错误报告或不发送重启，或点了“不发送”后，频繁重启或但是无论点击哪个按钮，无法打开EXCEL，无任何反应。

Excel遇到问题需要关闭、频繁重启或提示发送错误报告的解决办法

一、WORD的类似问题，解决方法如下：

方法1：如果还能进入WORD，直接另存为“文件模板”，就会看到一个“Normal”的文件，把她删除即可。方法2：如果WORD打不开，可在开始、运行中输入“winword -a”（不含引号）打开word安全模式，再用方法1解决。

方法3：在C:\Documents and Settings\Administrator\Application Data\Microsoft\Templates文件夹下找到“Normal”文件删除即可，如果打不到Application Data\Microsoft\Templates文件夹，在工具、文件夹选项中将查看选项下的显示隐患文件和系统文件选中，就可以找到了。

二、EXCEL解决方法：

方法1：进入“C:\Documents and Settings\Administrator\Application Data\Microsoft\Excel"文件夹，把里面后缀名为“.xlb”的文件全部删除，然后进入“XLSTART”文件夹，把里面的内容也全部删除，问题即可解决。症状2：

打开两个EXCEL工作簿，焦点不能随活动文档转换，即任务栏激活了任何一个工作簿，再想选择单元格等内容，无法选择，非要再激活别的什么文件，然后再转回来激活此文件一回，才把焦点抢夺回来，单元格可选了。WORD文档也可能会有类似情况。解决办法：

在WINDDOWS系统桌面右键单击－－属性－－外观－－效果，把“在菜单下显示阴影”前面的钩去掉。

出现此类问题可能是使用了精简的OFFICE安装盘，在此提示大家在使用软件时，尽量使用完整版的安装文件，因为各种精简版的软件常会引起各种奇奇怪怪的冲突。